競馬であそぶ ５

9. 　 Win32::OLE と Win32::OLE::Variant 　

本題の前に、一番最初に紹介した Perl モジュールの Config::Simple と ini ファイル について
簡単に書きます。
このファイルで保存用のパス設定、オッズデータの選択、取得タイムの設定と記録を行い ます。
先ず、JVSET.ini と名付けていますが、ini ファイル。

[pass]
rcovP=h:/others/rcov/
rtdatP=h:/others/rtdat/
yobiP=h:/others/yobi/
oddsP=h:/others/odds/

[odds]
oz_tnfw=1
oz_uren=1
oz_utan=1
oz_wide=1
oz_3fuk=1
oz_3tan=1
oz_odds=0

[default]
FromTime=20050601000000
RACETime=20050601000000
YSCHTime=20050601000000

Config::Simple を使う目的は
　1.　最終的には、スクリプトを直接、触らずに済ませたい。
　2.　FromTime などを保存しておく場所が必要。但し、簡単に変更 できるように

パスは必ず設定しておいてください。エディタなどで書き換えておきます。
odds の部分で対応するところを 0 にすると、取得しません。(←説明追加)
ini ファイルへのスクリプトからの書き込みは、下記のように行います。

        $cfg->param("default.RACETime", $ltm->Value() ) ;
        $cfg->write() ;

取り込みは下のようにして、右側の値を取得します。下は[pass] の rcovP の値。

    $cfg->param("pass.rcovP")

---

Win32::OLE はPPM などで、インストールする必要があります。
コマンドラインから、ppm　と打ち込んで起動した後、

ppm> install win32-ole

の要領ですね。Perl5 がインストールされていればコレだけです。多分、、

---

★ 以上で準備が完了 ★以下、本題。
前回からの修正部分については、Win32::OLE::Variant を使うことで解決 ということなのですが、
JVGets に関してはイマダ不明の部分があり、今回は JVRead を採りました。
これで支障あれば、もう一度JVGets を調べてみようと思います。
( ↑ 解決。JVOPT の使い方の案内 参照 )

まず、毎週取得する非蓄積系のデータに対するスクリプトです。 細かい部分については、
JRA-VAN Data Lab. JVData 仕様書　と JV-Link インターフェース仕様書 を参照してください。

sub get_weekly {    # 非蓄積系データ取得
    my $ds = Variant( VT_BSTR, 'RACERCOV' ) ;
    my $ftm = Variant( VT_BSTR, $cfg->param("default.RACETime") ) ;
    my $op = Variant( VT_I4, 2 ) ;
    my $rco = Variant( VT_I4|VT_BYREF, 0 ) ;
    my $dco = Variant( VT_I4|VT_BYREF, 0 ) ;
    my $ltm = Variant( VT_BSTR|VT_BYREF, '' ) ;
    my $rtn = $jvd->JVOpen( $ds, $ftm, $op, $rco, $dco, $ltm ) ;
    my $i = 0 ;
    RTR: while ( $rtn > 400 and $rtn < 440 ) {
        $rtn = $jvd->JVOpen( $ds, $ftm, $op, $rco, $dco, $ltm ) ;
        $i++ ;
        last RTR if $i > 2 ;
    }
    if ( $rtn == 0 ) {
        $cfg->param("default.RACETime", $ltm->Value() ) ;
        $cfg->write() ;
        my $dir = $cfg->param("pass.rcovP") ;
        my $bsize = Variant( VT_I4, 5120 ) ;
        my $pbuf = Variant( VT_UI1, "\x00" x 5120 ) ;
        my $buff = Variant( VT_BSTR|VT_BYREF, \$pbuf ) ;
        my $fn = Variant( VT_BSTR|VT_BYREF, '' ) ;  # ファイル名
        my @dat = () ;      my $i = 0 ;
        my $flg ;
        while ( $flg = $jvd->JVRead( $buff, $bsize, $fn ) ) {
            next if $fn =~ /^H[16]/i ;      # 票データは除外
            next if $fn =~ /^[OB]/i ;       # アタマに O と B がつくのは除外
            if( $flg > 0 ) {
                $dat[$i] = $buff->Value() ;
                $i++ ;
            } elsif( $flg == -1 ) {
                my $fname = $dir . substr( $fn, 0, 12) . '.dat' ;
                open DAT, ">$fname" ;
                for( @dat ) {
                    s/\x00+//g ;    s/\r// ;
                    print DAT $_ ;
                }
                @dat = () ;             $i = 0 ;
                close DAT ;
                print "\t\t読み込み完了。→ $fn\n" ;
            } else {
                 print " 非蓄積系データ・読み込みエラー。$flg\n" ;
            }
        }
    } elsif ( $rtn == -1 ) {
        print "新しいデータはありません。\n" ;
    } elsif ( $rtn == -504 ) {
        print "サーバーメンテナンス中。\n" ;
    } else {
        print "非蓄積系データ・ＤＬエラ−。$rtn\n" ;
    }
    &jv_close() ;
}

RTR の部分は、たまにサーバーに弾かれたりするので対策したつもりですが、 未テストです。
他にも勘違いやミスがあるかもしれませんが、気がついたら自分で直すのココロあるよ。

---

次に、当日のオッズや馬体重その他のデータを取得するための基本スクリプトです。

sub get_sokuho {
    my ( $ds, $bs, $ps ) = @{ shift() } ;
    my $dsnum = substr( $ds, -2, 2) ;
    my $ymdbr = $dsnum < 17 ? $yymmdd : $yymmdd . $bbrr ;
    my $rtn = $jvd->JVRTOpen( $ds, $ymdbr ) ;
    my $i = 0 ;
    RTR: while ( $rtn > 400 and $rtn < 440 ) {
        $rtn = $jvd->JVRTOpen( $ds, $ymdbr ) ;
        $i++ ;
        last RTR if $i > 2 ;
    }
    if( $rtn == 0 ) {
        my $dir = $cfg->param( $ps ) ;
        unless ( $dsnum < 17 ) {
            mkdir "$dir$yymmdd" unless -d "$dir$yymmdd" ;
            $dir .= $yymmdd . '/' ;
        }
        my $bsize = Variant( VT_I4, $bs ) ;
        my $pbuf = Variant( VT_UI1,  "\x00" x $bs ) ;
        my $buff = Variant( VT_BSTR|VT_BYREF, \$pbuf ) ;
        my $fn = Variant( VT_BSTR|VT_BYREF, '' ) ;   # ファイル名
        my $flg ;
        my $i = 0 ;
        my @dat = () ;
        while ( $flg = $jvd->JVRead( $buff, $bsize, $fn ) ) {
            if( $flg > 0 ) {
                $dat[$i] = $buff->Value() ;
                $i++ ;
            } elsif( $flg == -1 ) {
                my $plus = $dsnum < 17 ? 12 : 16 ;
                my $fname = $dir . substr( $fn, 0, $plus ) . '.dat' ;
                open DAT, ">$fname" ;
                for ( @dat ) {
                    s/\x00+//g ;    s/\r// ;
                    print DAT $_ ;
                }
                close DAT ;
                @dat = () ;     $i = 0 ;
                print "\t\t読み込み完了。→ $bbrr: $dsnum: $fn\n" ;
            } else {
                print " 速報・読み込みエラー。 $flg\n" ;
            }
        }
    } elsif( $rtn == -1 ) {
        if ( $dsnum < 17 ) {
            print "速報・該当データがありません。$rtn\n" ;
        } else {
            print "該当オッズデータがありません。$bbrr:$dsnum\n" ;
        }
    } elsif ( $rtn == -504 ) {
        print "サーバーメンテナンス中。\n" ;
    } else {
        print "速報・ＯＰＥＮエラー。$rtn\n" ;
    }
    &jv_close() ;
}

引数に応じてオッズと他情報とを分けています。面倒ならもっと簡単に作ったほうがいいかも
しれません。
オッズの場合、取得用のパスの中に日付のディレクトリを作っていたりします。

---

最後に、蓄積系の中から開催スケジュールを取り上げます。

sub get_schedule {  # 開催スケジュール取得
    my $ds = Variant( VT_BSTR, 'YSCH' ) ;
    my $ftm = Variant( VT_BSTR, $cfg->param("default.YSCHTime") ) ;
    my $op = Variant( VT_I4, 1 ) ;
    my $rco = Variant( VT_I4|VT_BYREF, 0 ) ;
    my $dco = Variant( VT_I4|VT_BYREF, 0 ) ;
    my $ltm = Variant( VT_BSTR|VT_BYREF, '' ) ;
    my $rtn = $jvd->JVOpen( $ds, $ftm, $op, $rco, $dco, $ltm ) ;
    if ( $rtn == 0 ) {
        $cfg->param("default.YSCHTime", $ltm->Value() ) ;
        $cfg->write() ;
        my $dir = $cfg->param("pass.rcovP") ;
        my $bsize = Variant( VT_I4, 512 ) ;
        my $pbuf = Variant( VT_UI1, "\x00" x 512 ) ;
        my $buff = Variant( VT_BSTR|VT_BYREF, \$pbuf ) ;
        my $fn = Variant( VT_BSTR|VT_BYREF, '' ) ;  # ファイル名
        my $flg ;
        my $i = 0 ;
        my @dat = () ;
        while ( $flg = $jvd->JVRead( $buff, $bsize, $fn ) ) {
            if( $flg > 0 ) {
                $dat[$i] = $buff->Value() ;
                $i++ ;
            } elsif( $flg == -1 ) {
                my $fname = $dir . substr( $fn, 0, 8) . '9999.dat' ;
                open DAT, ">$fname" ;
                for ( @dat ) {
                    s/\x00+//g ;    s/\r// ;
                    print DAT $_ ;
                }
                $i = 0 ;            @dat = () ;
                close DAT ;
                print "\t\t新しい開催スケジュール読み込み完了。\n" ;
             } else {
                 print " 開催スケジュール・読み込みエラー。 $flg\n" ;
            }
        }
    } elsif ( $rtn == -1 ) {
        print "新しい開催スケジュールはありません。\n" ;
    } elsif ( $rtn == -504 ) {
        print "サーバーメンテナンス中。\n" ;
    } else {
        print "開催スケジュール・ＤＬエラ−。$rtn\n" ;
    }
    &jv_close() ;
}